AD9851 DDS 50Mhz水晶発振子代替PCB版

Arduino UNOを使ったAD9851　DDS水晶発振子代替PCB版。公開中のプロトタイプをPCB化した物で、パターン引き回し上、DIOアドレスを変更。　水晶発振子代替と表現しているが、水晶発振クオリティを目指したものでは無い。　DDSクオリテイのチャンネル切替式である。バッファアンプは同調方式を採用し、クリーンな増幅をしている。簡易スペアナで見る限り、スプリアスは見当たらない。ただ、受信機でモニターすると、多少、ざわつき（DDS固有かも知れないが・・・）を感じる。問題になるレベルでないと思う。　

回路図である。チャンネル切替方式に必要な所以外、書いてない。チェンネル切替が不要であれば、50.6Mhz（デフォルト）一波となる。送信切替は、接点入力／電圧入力可能。出力は、真空管ドライブ可能なレベルである。

基板サイズ　６９　ｘ　５４

Program（スケッチ）

50Mhz　AM　送信用水晶発振子の代替とすべく、チャンネル周波数を設定している。このプログラムでは、受信時、DDS発振を停止している。送受用DDSに変更も簡単だ。

//////////////////////////////////////////////////////////////////////
//  AD9851 DDS VFO Premixed type program ver.1.0
//
//    Copyright(C)2014-2015.JA2GQP.All rights reserved.
//     Crystal replacement
//                                                  2015/8/26
//                                                  JA2GQP
//--------------------------------------------------------------------
//  Function
//    1.ch0=50.6Mhz ch1=50.55Mhz ch2=50.62Mhz ch3=50.69Mhz
//    2.TX=chenel frequency RX=0Hz(off)
//////////////////////////////////////////////////////////////////////

//----------  Define Constant Value   ----------
                                             
const byte  DATA = 12;                       // DIO12
const byte  W_CLK = 14;                      // DIO14
const byte  FQ_UD = 15;                      // DIO15

const byte  SW_CH1 = 9;                      // Channel 1
const byte  SW_CH2 = 10;                     //         2
const byte  SW_CH3 = 11;                     //         3
const byte  SW_TX = 13;                      // TX Sw
const byte  DDS_RST = 8;                     // DDS Reset

const long  FRQ_CH0 = 50600000L;             // CH0=50.6Mhz
const long  FRQ_CH1 = 50550000L;             // CH1=50.55Mhz
const long  FRQ_CH2 = 50620000L;             // CH2=50.62Mhz
const long  FRQ_CH3 = 50690000L;             // CH3=50.69Mhz

const unsigned long  DDS_CLK = 192000000L;   // AD9851 Clock(32MHz * 6)
const unsigned long  TWO_E32 = 4294967295L;  // 2^32
const byte  DDS_CMD = B00000001;             // AD9851 Command

//----------  Memory Assign  -------------------

long Dds_Dat = 0;                             // DDS Data

//----------  Initialization  Program  ---------------

void setup(){
  pinMode(SW_TX,INPUT_PULLUP);                // Input pin set
  pinMode(SW_CH1,INPUT_PULLUP);
  pinMode(SW_CH2,INPUT_PULLUP);
  pinMode(SW_CH3,INPUT_PULLUP);

  pinMode(DDS_RST,OUTPUT);                   // Output pin set
  pinMode(FQ_UD,OUTPUT);
  pinMode(W_CLK,OUTPUT);
  pinMode(DATA,OUTPUT);

  Fnc_Dds_Int();                             // DDS Initial
}

//----------  Main program  ---------------

void loop() {
  if(digitalRead(SW_CH1) == LOW){
    Dds_Dat = FRQ_CH1;
    }
  else if(digitalRead(SW_CH2) == LOW){
    Dds_Dat = FRQ_CH2;
    }
  else if(digitalRead(SW_CH3) == LOW){
    Dds_Dat = FRQ_CH3;
    }
    else{
      Dds_Dat = FRQ_CH0;
      }

  if(digitalRead(SW_TX) == HIGH){            // Rx?
    Dds_Dat = 0L;
    }

  Fnc_Dds(Dds_Dat);
  delay(100);
}


//----------  Function DDS Initialization  ---------------

void Fnc_Dds_Int(){
  digitalWrite(DDS_RST,HIGH);
  delay(1);
  digitalWrite(DDS_RST,LOW);
  digitalWrite(W_CLK,HIGH);
  digitalWrite(W_CLK,LOW);
  digitalWrite(FQ_UD,HIGH);
  digitalWrite(FQ_UD,LOW);
}

//----------  Function DDS set  ---------------

void Fnc_Dds(double frquency){
  unsigned long wrk = frquency * TWO_E32 / DDS_CLK;

  digitalWrite(FQ_UD,LOW);

  shiftOut(DATA,W_CLK,LSBFIRST,wrk);
  shiftOut(DATA,W_CLK,LSBFIRST,(wrk >> 8));
  shiftOut(DATA,W_CLK,LSBFIRST,(wrk >> 16));
  shiftOut(DATA,W_CLK,LSBFIRST,(wrk >> 24));
  shiftOut(DATA,W_CLK,LSBFIRST,DDS_CMD);   // AD9851 command

  digitalWrite(FQ_UD,HIGH);
}

AD9851 DDS 水晶発振子代替

50Mhz　AM送信機の水晶発振子代替として、AD9851 DDSを使った。送受信機の場合、一般的にDDS発振周波数を替えて、VFO送受共用にしている。しかし、送信機に使う場合、常時発振していては、受信機にキャリア漏れで、悪影響がある。そこで、送信時のみDDS発振し、受信時はDDS発振停止とした。DDS出力は、真空管ドライブ可能な+10dbm程。

回路図は、DDS　VFOとして機能する様、フルスペックで書いて有る。今回の仕様は、チャンネル切替式の為、破線部分は不要。

ｐｒｏｇｒａｍ

最小限の機能なので、DDS入門に適している。公開済のArduino　AD9851　VFOでDDSが発振しない事（原因は、DDS　Reset）が有った。今回、DDS　Resetを含め、シンプルに纏めた。

//////////////////////////////////////////////////////////////////////

//  AD9851 DDS program ver.1.0

//

//    Copyright(C)2014-2015.JA2GQP.All rights reserved.

//     Crystal replacement

//                                                  2015/8/3

//                                                  JA2GQP

//--------------------------------------------------------------------

//  Function

//    1.ch0=50.6Mhz ch1=50.55Mhz ch2=50.62Mhz ch3=50.69Mhz

//    2.TX=chenel frequency RX=0Hz(off)

//////////////////////////////////////////////////////////////////////

//----------  Define Constant Value   ----------

                                                

const byte  DATA = 4;                        // DIO4

const byte  W_CLK = 5;                       // DIO5

const byte  FQ_UD = 6;                       // DIO6

const byte  SW_CH1 = 10;                     // Channel 1

const byte  SW_CH2 = 11;                     //         2

const byte  SW_CH3 = 12;                     //         3

const byte  SW_TX = 13;                      // TX Sw

const byte  DDS_RST = 14;                    // DDS Reset

const long  FRQ_CH0 = 50600000L;             // CH0=50.6Mhz

const long  FRQ_CH1 = 50550000L;             // CH0=50.55Mhz

const long  FRQ_CH2 = 50620000L;             // CH0=50.62Mhz

const long  FRQ_CH3 = 50690000L;             // CH0=50.69Mhz

const unsigned long  DDS_CLK = 192000000L;   // AD9851 Clock(32MHz * 6)

const unsigned long  TWO_E32 = 4294967295L;  // 2^32

const byte  DDS_CMD = B00000001;             // AD9851 Command

//----------  Memory Assign  -------------------

long Dds_Dat = 0;                             // DDS Data

//----------  Initialization  Program  ---------------

void setup(){

  pinMode(SW_TX,INPUT_PULLUP);                // Input pin set

  pinMode(SW_CH1,INPUT_PULLUP);

  pinMode(SW_CH2,INPUT_PULLUP);

  pinMode(SW_CH3,INPUT_PULLUP);

  pinMode(DDS_RST,OUTPUT);                   // Output pin set

  pinMode(FQ_UD,OUTPUT);

  pinMode(W_CLK,OUTPUT);

  pinMode(DATA,OUTPUT);

  Fnc_Dds_Int();                             // DDS Initial

}

//----------  Main program  ---------------

void loop() {

  if(digitalRead(SW_CH1) == LOW){

    Dds_Dat = FRQ_CH1;

    }

  else if(digitalRead(SW_CH2) == LOW){

    Dds_Dat = FRQ_CH2;

    } 

  else if(digitalRead(SW_CH3) == LOW){

    Dds_Dat = FRQ_CH3;

    }

    else{

      Dds_Dat = FRQ_CH0;

      }

  

  if(digitalRead(SW_TX) == HIGH){            // Rx?

    Dds_Dat = 0L;

    }

  Fnc_Dds(Dds_Dat);

  delay(100);

}  

//----------  Function DDS Initialization  ---------------

void Fnc_Dds_Int(){

  digitalWrite(DDS_RST,HIGH);

  delay(1);

  digitalWrite(DDS_RST,LOW);

  digitalWrite(W_CLK,HIGH);

  digitalWrite(W_CLK,LOW);

  digitalWrite(FQ_UD,HIGH);

  digitalWrite(FQ_UD,LOW);

}

//----------  Function DDS set  ---------------

void Fnc_Dds(double frquency){

  unsigned long wrk = frquency * TWO_E32 / DDS_CLK;

  

  digitalWrite(FQ_UD,LOW);

  shiftOut(DATA,W_CLK,LSBFIRST,wrk);

  shiftOut(DATA,W_CLK,LSBFIRST,(wrk >> 8));

  shiftOut(DATA,W_CLK,LSBFIRST,(wrk >> 16));

  shiftOut(DATA,W_CLK,LSBFIRST,(wrk >> 24));

  shiftOut(DATA,W_CLK,LSBFIRST,DDS_CMD);   // AD9851 command

  digitalWrite(FQ_UD,HIGH);

}

  

　　　　　

Arduino IDE1.6.3 Bug

Arduino IDEを何気なくVersion UPした所、DDS　VFOのSTEPが誤表示。今迄、新版と旧版を気にしてなかったが、新版1.6.Xで確実に起きる現象だ。感じとして、デバイスのタイミングを狂わせる要素が有る様に思える。次期Versionで回収されると期待し、1.6.2を使っていたが、1.6.3でも改修されてない。矢張り新版はリスクがあり、旧版1.0.6を使うべきだ。
　

修正前のプログラム（新版で、誤動作）
誤表示は、STEPである。事前に表示を消してから、データ表示する様にしている。また、表示クリアーの桁数を変更しても、誤表示する。（インターバル処理をしているかの様な感じの誤動作）

修正後のプログラム（旧版、新版とも正常）
新版1.6.Xで正常表示を行う様に修正したモジュール。（メモリーが十分有るので、こんな書き方でも良いのだが・・・・）
　

正常な表示。　  

６BQ5ｼﾝｸﾞﾙ変調器

電源回路にFETﾘｯﾌﾟﾌｨﾙﾀを使った6BQ5ｼﾝｸﾞﾙ変調器。ｼｬｰｼ流用の為、最適な配置ではない。12AX7と6BQ5で構成し、ｱｳﾄﾌﾟｯﾄﾄﾗﾝｽを使った。　

線材は、真空管ﾗｼﾞｵのﾒﾝﾃﾅﾝｽ用に保管の絹巻き線を使用。真空管の配線作業は久しぶりで、思わぬﾄﾗﾌﾞﾙに遭遇した。それは、ﾏｲｸを外した状態で、ﾎﾞﾘｭｰﾑを回すとｼﾞｰ音が発生した事だ。初めﾘｯﾌﾟﾙﾌｨﾙﾀを疑ったが、電源ﾊﾑより周波数が高いので、ﾋｰﾀ回路のｱｰｽを忘れている事が判った。手順の悪さが作ったﾄﾗﾌﾞﾙかも知れない。

配線図。現状では、送信部が無いのでﾏｲｸｱﾝﾌﾟ。ﾘｯﾌﾟﾙﾌｨﾙﾀ周りの電圧は、実測値。(計算値も一致）
　　　　　　　　　

STM32-SDR

SoftRock RxTx Ensemble KitをPCなしで使う事が出来るSTM32をﾍﾞｰｽとしたSDR　TRXで、STM32-SDRと呼ばれている。昨年末に組立て、今日に至る。現時点で、PSK31、SSBおよびCWの3ﾓｰﾄﾞが可能。製作したSTM32-SDRは、専用ｴﾝｸﾛｰｼﾞｬに収納した為、内部のﾜｲｱﾘﾝｸﾞは殆ど無い。部品入手は、SoftRock RxTx Ensemble Kitは、別ｼｮｯﾌﾟなので注意。
写真は参考(ﾊﾟﾗﾒｰﾀがﾃﾞﾌｫﾙﾄ)。

裏蓋を外した様子。
SoftRock RxTx Ensemble Kitを組立て、動作確認した後、STM32-SDR用に改造した。ICｿｹｯﾄU1の取り外しは苦労したので、ICｿｹｯﾄを壊して外すのが良いかも知れない。ﾍｯﾀﾞ、ｿｹｯﾄなど現物調整が要る。　　　　

ﾏｲｸ、ｲﾔﾌｫﾝ側の様子。
ﾏｻﾞｰﾎﾞｰﾄﾞとの接続部分は、要注意。
また、組立ﾏﾆｭｱﾙ、最新情報入手など、yahoo　Gropsからﾀﾞｳﾝﾛｰﾄﾞする事となるので、yahoo.comにｱｶｳﾝﾄが必要。
　　

FET リップルフィルタ

真空管電源用のFETﾘｯﾌﾟﾙﾌｨﾙﾀである。50年程前、LCRにる電源ﾌｨﾙﾀであったが、今では半導体を使ったﾘｯﾌﾟﾙﾌｨﾙﾀも使われている。現在、主にｵｰﾃﾞｨｵAMPの電源部として使われているが、無線機の電源部として使う予定。FETは、手持ちの中から、VDSSの高いものを選んだ。ﾁｮｰｸﾚｽ構成の為、重量低減とﾛｰｺｽﾄ化を狙える。ただ、ﾄﾗﾝｽと組み合わせた確認試験を行ってないので、性能は定かでない。　

回路図である。回路図中の電圧は、無負荷時の計算値。

PCBｻｲｽﾞ　83×58
抵抗は、無理すれば、3Wまでなら実装可能。　　　　　　　　　　

秋月電子DDS（TC170C030) VFO

長い間眠っていた秋月電子のDDSｷｯﾄを組立て、DDS　VFOを作った。今回も、I2CｺﾝﾄﾛｰﾙのLCDを使って、省配線。Aruduinoが安価（中華ｻｲﾄで$4位）なので、ﾃｽﾄするのに助かる。公開済のArduino版ﾌｧｰﾑｳｪｱを移植したので、機能は問題ない筈だ。また、秋月DDSをVFOとして使う場合、最大出力周波数に注意しなければならない。このｷｯﾄの場合、ﾃﾞｰﾀｼｰﾄから約16MHzである。

回路図である。LPFはｼｭﾐﾚｰｼｮﾝにより、ｶｯﾄｵﾌ16MHzで設計。ｼｭﾐﾚｰｼｮﾝの様子は、Twitterに書き込んである。

Program

公開済みのArduino版ﾌｧｰﾑｳｪｱを移植した。ﾃﾞﾊﾞｲｽ固有の部分は、DDS出力ﾙｰﾁﾝである。今までのIF=10MHzとしたﾌﾟﾘﾐｯｸｽでｱｯﾊﾟｰﾍﾃﾛﾀﾞｲﾝでは、DDS最大出力周波数を超えてしまう。そこでIF=5MHzとした。IFを10MHzとする場合、逆ﾍﾃﾛﾀﾞｲﾝとなる。何れのｿｰｽﾌﾟﾛｸﾞﾗﾑもDownload　siteにupしてある。

//////////////////////////////////////////////////////////////////////
//  TC170C030AF001 DDS VFO Premixed type program ver.1.0
//
//    Copyright(C)2014-2015.JA2GQP.All rights reserved.
//
//      7.000MHz to 7.200MHz Limitted.
//      (Target frequency = IF frquency + frequency)
//                                                  2015/04/14
//                                                  JA2GQP
//--------------------------------------------------------------------
//  Function
//    1.RIT Operation(-50kHZ to 50kHZ)
//    2.STEP(100k,10k,1k,100,10)
//    3.Memory Operation is Push RIT
//      (Frequency and Step)
//    4.Protection Operation At The Time Of Transmission
//    5.Channel Memory.Main Channel(Ch0) + 3 Channel(Ch1,Ch2,Ch3)
//    6.Split Operation(7.00MHz to 7.20MHz Limited!)
//
//////////////////////////////////////////////////////////////////////

#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <rotary.h>
#include <EEPROM.h>

//----------  LCD Pin Assign  ------------------

LiquidCrystal_I2C lcd(0x27,16,2);       // set the LCD address to 0x27 for
                                             　　　// a 16 chars and 2 line display

//----------  Define Constant Value   ----------
                                             
const byte  ENC_A = 2;                   // Encorder A
const byte  ENC_B = 3;                   //          B
const byte  DDT = 4;                      // TC170C030AF001 DATA
const byte  DCK = 5;                      //                SCK
const byte  DST = 6;                      //                STB
const byte  SW_STEP = 7;               // STEP Sw
const byte  SW_RIT = 8;                  // RIT Sw
const byte  SW_SPLIT = 9;               // SPLIT Sw
const byte  SW_CH1 = 10;                // Channel 1
const byte  SW_CH2 = 11;                //         2
const byte  SW_CH3 = 12;                //         3
const byte  SW_TX = 13;                  // TX Sw

const long  IF_FRQ = 5001500L;        // IF Frequency
const long  LW_FRQ = 7000000L;       // Lower Limit
const long  HI_FRQ = 7200000L;        // Upper Limit
const long  DEF_FRQ = 7050000L;     // Init Frequency
const long  DEF_STP = 1000L;          // Init STEP
const long  LW_RIT = -50000L;          // RIT Lower Limit
const long  HI_RIT = 50000L;             //     Upper Limit
const long  LW_VFO = IF_FRQ + LW_FRQ;     // Vfo Lower Limit
const long  HI_VFO = IF_FRQ + HI_FRQ;     　//     Upper Limit
const long  DEF_VFO = IF_FRQ + DEF_FRQ;  // Vfo Default Frequency

const unsigned long  DDS_CLK = 67108864L; // TC170C030AF001 Clock 67.108864Mhz
const unsigned long  TWO_E26 = 67108864L; // 2^26
const byte  DDS_CMD1 = B00110011;         　// CM3=1,CM2=1,CM1=0,CM0=0
                                          　　　　　　　　　　// A2=1,A1=1
const byte  DDS_CMD2 = B00000001;         　// A0=1
                                       

//----------  EEPROM Memory Address   ----------

const byte  Frq_Eep0 = 0x00;               // Frequency Ch0
const byte  Frq_Eep1 = 0x04;               //           Ch1                                              
const byte  Frq_Eep2 = 0x08;               //           Ch2
const byte  Frq_Eep3 = 0x0c;               //           Ch3

const byte  Stp_Eep0 = 0x10;               // STEP Ch0
const byte  Stp_Eep1 = 0x14;               //      Ch1                                              
const byte  Stp_Eep2 = 0x18;               //      Ch2
const byte  Stp_Eep3 = 0x1c;               //      Ch3

//----------  Encorder Pin Assign(INT)  --------

Rotary r = Rotary(ENC_A,ENC_B);            // 2 = ENC_A,3 = ENC_B

//----------  Memory Assign  -------------------

long Vfo_Dat = 0;                         　　　// VFO Data
long Dds_Dat = 0;                        　　　 // DDS Data
long Rit_Dat = 0;                         　　　// RIT Data
long Rit_Datb = 0;                        　　　// RIT Data Old
long Enc_Stp = 0;                        　　　 // STEP
long Lng_Wk1 = 0;                         　　　// Long Work1
long Lng_Wk2 = 0;                         　　　// Long Work2

char *Lcd_Dat = "           ";            　　// Lcd Display Buffer

byte Byt_Chn = 0;                         　　　// Channel SW
byte Byt_Chnb = 0;                        　　　// Channel SW Old
byte Flg_Rit = 0;                         　　　　// RIT Flag
byte Flg_Ritb = 0;                        　　　　// RIT Flag Old
byte Flg_Tx = 0;                         　　　　 // TX Flag
byte Flg_Spl = 0;                         　　　　// SPLIT Flag

//----------  Initialization  Program  ---------------

void setup(){
  lcd.init();                            　// initialize the lcd
  lcd.backlight();                       // LCD backlight on

  pinMode(SW_STEP,INPUT_PULLUP);
  pinMode(SW_RIT,INPUT_PULLUP);
  pinMode(SW_SPLIT,INPUT_PULLUP);
  pinMode(SW_TX,INPUT_PULLUP);
  pinMode(SW_CH1,INPUT_PULLUP);
  pinMode(SW_CH2,INPUT_PULLUP);
  pinMode(SW_CH3,INPUT_PULLUP);

  PCICR |= (1 << PCIE2);
  PCMSK2 |= (1 << PCINT18) | (1 << PCINT19);
  sei();                                 // INT Enable

  pinMode(DST,OUTPUT);
  pinMode(DCK,OUTPUT);
  pinMode(DDT,OUTPUT);

  Flg_Tx = 0;
  Flg_Rit = 0;
  Flg_Spl = 0;

  lcd.clear();
  Fnc_Chsw();                            // Channel Sw Read
  Byt_Chnb = Byt_Chn;
  Fnc_Eep_Rd();                          // EEPROM Read
}

//----------  Main program  ---------------

void loop() {
  if(Flg_Tx == 0){                       　　　　　// Tx off?
    if(digitalRead(SW_STEP) == LOW){     // STEP Sw On?
      Fnc_Stp();                         　　　　　//     Yes,STEP proc.
    }
    if(digitalRead(SW_RIT) == LOW){      // RIT Sw On?
      Fnc_Rit();                         　　　　　//     Yes,RIT proc.
    }
    if(digitalRead(SW_SPLIT) == LOW){    // SPLIT Sw On?
      Fnc_Spl();                        　　　　　 //     Yes,SPLIT proc.
    }
    Fnc_Chsw();                          　　　　// Channel Sw read
 
    if(Byt_Chnb != Byt_Chn){             　　// Channnel SW Chenge?
      if(Byt_Chnb == 0){                 　　　// Channnel 0?    
        Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep0);  //   Yes,Vfo_Dat Save
        Fnc_Eep_Sav4(Enc_Stp,Stp_Eep0);  //       Enc_Step Save
        Flg_Ritb = Flg_Rit;
        Rit_Datb = Rit_Dat;
        Flg_Rit = 0;
        Flg_Spl = 0;
        Rit_Dat = 0;
      }
   
      if(Byt_Chnb != 0){                 　　　　// Other(Ch1-Ch3) Channnel?
        Flg_Rit = 0;
        Flg_Spl = 0;
        if((Byt_Chn == 0) && (Flg_Ritb == 1)){
          Flg_Rit = 1;
          Rit_Dat = Rit_Datb;
        }
      }
     
      Byt_Chnb = Byt_Chn;
      Fnc_Eep_Rd();
    }
  }
  if(digitalRead(SW_TX) == LOW){         // Tx On?
    Flg_Tx = 1;                          　　　　//    Yes,Flg_Tx Set
  }
  else{                                  
    Flg_Tx = 0;                          　　　　//     No,Flg_Tx Reset              
  }

  if(Flg_Rit == 1){                      　　　　// RIT?
    Dds_Dat = Vfo_Dat + Rit_Dat;         //    Yes,Dds_Dat Set
  }
  else{
    Dds_Dat = Vfo_Dat;                   　　//    No,Dds_Dat Set
  }

  if(Flg_Tx == 1){                      　　　　 // Tx?
    if(Flg_Spl == 1){                    　　　　// SPLIT?
      Dds_Dat = Vfo_Dat + Rit_Dat;       　//    Yes,Dds_Dat Set
    }
      else{
        Dds_Dat = Vfo_Dat;               　　　//    No,Dds_Dat Set
      }
  }
  Fnc_Dds(Dds_Dat);                     　　　 // TC170C030AF001 DDS Out
  Fnc_Lcd();                             　　　　// LCD Display
  delay(100);
}

//----------  Encorder procedure(INT)  ---------------

ISR(PCINT2_vect) {
  unsigned char result = r.process();

  if(Flg_Tx == 0){
    if(result) {  
      if(result == DIR_CW){
        Lng_Wk1 = Vfo_Dat + Enc_Stp;
        Lng_Wk2 = Rit_Dat + Enc_Stp;
      }
      else{
          Lng_Wk1 = Vfo_Dat - Enc_Stp;
          Lng_Wk2 = Rit_Dat - Enc_Stp;
      }    
      if((Flg_Rit == 1) || (Flg_Spl == 1)){
        Rit_Dat = Lng_Wk2;
      }
      else{
        Vfo_Dat = Lng_Wk1;
        Rit_Dat = 0;
      }
      Vfo_Dat = constrain(Vfo_Dat,LW_VFO,HI_VFO);

      if(Flg_Spl == 1){
        Rit_Dat = constrain(Rit_Dat,(LW_VFO - Vfo_Dat),(HI_VFO - Vfo_Dat));
      }
      else{
        Rit_Dat = constrain(Rit_Dat,LW_RIT,HI_RIT);
      }
    }
  }
}

//----------  Function DDS set  ---------------

void Fnc_Dds(double frquency){
  unsigned long wrk = frquency * TWO_E26 / DDS_CLK;
  unsigned int wrk1,wrk2;

  wrk1 = wrk >> 10;
  wrk2 = wrk << 6;
  wrk2 = wrk2 & 0xffc0 | DDS_CMD1;

  digitalWrite(DDT,DDS_CMD2 & 0x01);
  digitalWrite(DCK,HIGH);
  digitalWrite(DCK,LOW);

  shiftOut(DDT,DCK,LSBFIRST,wrk2);
  shiftOut(DDT,DCK,LSBFIRST,(wrk2 >> 8));

  shiftOut(DDT,DCK,LSBFIRST,wrk1);
  shiftOut(DDT,DCK,LSBFIRST,(wrk1 >> 8));

  digitalWrite(DST,LOW);
  digitalWrite(DST,HIGH);
}

//----------  Function Encorder STEP  ---------

void Fnc_Stp(){
  if(Enc_Stp == 10){                      // Step = 10Hz ?
    Enc_Stp = 100000;                     //   Yes,100khz set
    }
    else{
      Enc_Stp = Enc_Stp / 10;             // Step down 1 digit
      }
  delay(100);
  Fnc_Step_Disp();
  Fnc_Lcd();
  while(digitalRead(SW_STEP) == LOW)
    ;
  delay(250);
}

//----------  Function STEP Display  ----------

void Fnc_Step_Disp(){
  lcd.setCursor(0,1);
  switch(Enc_Stp){
    case 10:
      lcd.print("10  ");
      break;
    case 100:
      lcd.print("100 ");
      break;
    case 1000:
      lcd.print("1k  ");
      break;
    case 10000:
      lcd.print("10k ");
      break;
    case 100000:
      lcd.print("100k");
      break;
  }
}

//----------  Function String Dot Edit  --------
 
char *Fnc_Dot_Edit(char *str,long n){
  int  i = 0;                           // Write the number
  char *p = str;
  unsigned long  u = abs(n);

  do{
    *p++ = "0123456789"[u % 10];
    u = u / 10;
    i++;
    if((0 != u) && (0 == (i % 3)))
      *p++ = '.';
    }
  while( 0 != u );

  if ( n < 0 )
     *p++ = '-';
   *p = '\0';
   Fnc_Revr( str );
   return str;
}

//----------  Function String Reverse  ---------

void Fnc_Revr(char *str){
  int i,n;
  char c;

  n=strlen(str);
  for(i = 0;i < n / 2;i++){
    c=str[i];
    str[i]=str[n - i - 1];
    str[n - i - 1]=c;
  }
}

//----------  Function Save EEPROM 2byte  ---------

void Fnc_Eep_Sav2(unsigned int value,int address){
  address += 1;
  for(int i = 0;i < 2;i++){
    byte toSave = value & 0xFF;
    if(EEPROM.read(address) != toSave){
      EEPROM.write(address,toSave);
      }
    value = value >> 8;
    address--;
  }
}

//----------  Function Save EEPROM 4byte  ---------

void Fnc_Eep_Sav4(long value,int address){
  address += 3;
  for(int i = 0;i < 4;i++){
    byte toSave = value & 0xFF;
    if(EEPROM.read(address) != toSave){
      EEPROM.write(address,toSave);
      }
    value = value >> 8;
    address--;
  }
}

//----------  Function Load EEPROM 2byte  ---------

unsigned int  Fnc_Eep_Lod2(int address){
  unsigned int value = EEPROM.read(address);
  value = value << 8;
  return value | EEPROM.read(address + 1);
}

//----------  Function Load EEPROM 4byte  ---------

long Fnc_Eep_Lod4(int address){
  long value = 0;
  for(int i = 0;i < 4;i++){
    value = value | EEPROM.read(address);
    if( i < 3){
      value = value << 8;
      address++;
      }
  }
  return value;
}

//----------  Function LCD Display  ---------

void Fnc_Lcd(){
  if(Flg_Tx == 1){
    lcd.setCursor(0,0);
    lcd.print("T");
  }
  else{
    lcd.setCursor(0,0);
    lcd.print(Byt_Chn);
  }

  Fnc_Step_Disp();

  if(Flg_Rit == 1){
    lcd.setCursor(5,1);
    lcd.print("R:          ");
    Fnc_Dot_Edit(Lcd_Dat,Rit_Dat);
    lcd.setCursor(7,1);
    lcd.print(Lcd_Dat);
    if((Rit_Dat >= 1000) || (Rit_Dat <= -1000)){
     lcd.print("k");
    }
  }

  if(Flg_Spl == 1){
    lcd.setCursor(5,1);
    lcd.print("X:          ");
    Fnc_Dot_Edit(Lcd_Dat,Rit_Dat);
    lcd.setCursor(7,1);
    lcd.print(Lcd_Dat);
    if((Rit_Dat >= 1000) || (Rit_Dat <= -1000)){
      lcd.print("k");
    }
  }

  if((Flg_Rit == 0) && (Flg_Spl == 0)){
    Fnc_Dot_Edit(Lcd_Dat,Vfo_Dat - IF_FRQ);
    lcd.setCursor(1,0);
    lcd.print(":              ");
    lcd.setCursor(3,0);
    lcd.print(Lcd_Dat);
    lcd.print("MHz");

    lcd.setCursor(5,1);
    lcd.print("     JA2GQP");
  }
}


//----------  Function Rit  ---------

void Fnc_Rit(){
  if(Flg_Rit == 0){
    Rit_Dat = 0;
    Flg_Rit = 1;
    Flg_Spl = 0;
    switch(Byt_Chn){
      case 1:
        Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep1);
        Fnc_Eep_Sav4(Enc_Stp,Stp_Eep1);
        break;
      case 2:
        Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep2);
        Fnc_Eep_Sav4(Enc_Stp,Stp_Eep2);
        break;
      case 3:
        Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep3);
        Fnc_Eep_Sav4(Enc_Stp,Stp_Eep3);
        break;
      default:
        Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep0);
        Fnc_Eep_Sav4(Enc_Stp,Stp_Eep0);
        break;
    }
  }
  else{
    Flg_Rit = 0;
  }
  while(digitalRead(SW_RIT) == LOW)
    ;
  delay(250);
}

//----------  Function Channel SW Check  ---------

void Fnc_Chsw(){
  if(digitalRead(SW_CH1) == LOW){
    Byt_Chn = 1;
  }
  else if(digitalRead(SW_CH2) == LOW){
    Byt_Chn = 2;
  }
  else if(digitalRead(SW_CH3) == LOW){
    Byt_Chn = 3;
  }
  else{
    Byt_Chn = 0;
  }
}

//----------  Function EEPROM Read  ---------

void Fnc_Eep_Rd(){
  if(Fnc_Eep_Lod4(Frq_Eep0) <= LW_VFO){
    Vfo_Dat = DEF_VFO;
    Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep0);
    Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep1);
    Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep2);
    Fnc_Eep_Sav4(Vfo_Dat,Frq_Eep3);
  }
  else{
    switch(Byt_Chn){
      case 1:
        Vfo_Dat = Fnc_Eep_Lod4(Frq_Eep1);
        break;
      case 2:
        Vfo_Dat = Fnc_Eep_Lod4(Frq_Eep2);
        break;
      case 3:
        Vfo_Dat = Fnc_Eep_Lod4(Frq_Eep3);
        break;
      default:
        Vfo_Dat = Fnc_Eep_Lod4(Frq_Eep0);
        break;
    }
  }
  if(Vfo_Dat <= 0){
    Vfo_Dat = DEF_VFO;
  }
  if(Fnc_Eep_Lod4(Stp_Eep0) <= 0){
    Enc_Stp = DEF_STP;
    Fnc_Eep_Sav4(Enc_Stp,Stp_Eep0);
    Fnc_Eep_Sav4(Enc_Stp,Stp_Eep1);
    Fnc_Eep_Sav4(Enc_Stp,Stp_Eep2);
    Fnc_Eep_Sav4(Enc_Stp,Stp_Eep3);
  }
  else{
    switch(Byt_Chn){
      case 1:
        Enc_Stp = Fnc_Eep_Lod4(Stp_Eep1);
        break;
      case 2:
        Enc_Stp = Fnc_Eep_Lod4(Stp_Eep2);
        break;
      case 3:
        Enc_Stp = Fnc_Eep_Lod4(Stp_Eep3);
        break;
      default:
        Enc_Stp = Fnc_Eep_Lod4(Stp_Eep0);
        break;
    }
  }
  if(Enc_Stp <= 0){
    Enc_Stp = DEF_STP;
  }
}

//----------  Function Split  ---------

void Fnc_Spl(){
  if(Flg_Spl == 0){
    Flg_Spl = 1;
    Flg_Rit = 0;
    Rit_Dat = 0;
  }
  else{
    Flg_Spl = 0;
  }
  while(digitalRead(SW_SPLIT) == LOW)
    ;
  delay(250);
}